Lección 1.3: Datos y variables
Un programa trabaja con datos. Para usarlos, los guarda en variables: cajas con nombre.
La idea
Una variable es una caja con nombre donde el programa guarda un dato.
- El nombre sirve para encontrarla:
edad,precio,nombre. - El valor es lo que hay dentro:
30,9.99,"Ana".
Para guardar un valor se usa la flecha ←:
edad ← 30
Se lee «edad toma el valor 30». Los nombres van sin espacios ni tildes: precioTotal, no precio total.
Una caja, un valor
Si guardas otro valor, el anterior desaparece:
Algoritmo Cumpleanos
edad ← 30
edad ← edad + 1
Escribir edad
FinAlgoritmo
31
La segunda línea se lee de derecha a izquierda: calcula edad + 1, que da 31, y lo guarda en edad.
Tipos de datos
Cada dato es de un tipo. Para empezar bastan tres:
| Tipo | Ejemplos | Para qué |
|---|---|---|
| Número | 30, 9.99, -4 | Contar y calcular |
| Texto | "Ana", "Hola" | Palabras y frases, siempre entre comillas |
| Lógico | Verdadero, Falso | Responder sí o no |
Ojo: 5 es un número y "5" es un texto. Con el primero se puede sumar; con el segundo, no.
Operaciones
Con números: +, -, * (multiplicar) y / (dividir).
precio ← 20
cantidad ← 3
total ← precio * cantidad
Escribir "Total: ", total
Total: 60
Pruébalo
Escribe un algoritmo que pida dos números y escriba su suma.
Ver la solución
Algoritmo Sumar
Escribir "Primer número:"
Leer a
Escribir "Segundo número:"
Leer b
suma ← a + b
Escribir "La suma es ", suma
FinAlgoritmo
En resumen
- Una variable es una caja con nombre que guarda un valor.
←guarda un valor y borra el que había.- Tres tipos para empezar: número, texto y lógico.